Встановлення характеристик апаратного середовища системи

Размещено на http://www.allbest.ru/

Зміст

Вступ

1. Постановка задачі

2. Опис алгоритму роботи програми

3. Тестування програми

Висновки

Список використаної літератури

Додаток А

Додаток Б

Вступ

Сучасній людині сьогодні важко уявити своє життя без електронно-обчислювальних машин. Шлях розвитку обчислювальної техніки був нелегким і довгим. Спочатку були прості машини, які виконували нескладні арифметичні операції. Старші люди пам'ятають широко розповсюджені півтора десятка років тому механічні арифмометри, винайдені ще в XVII столітті, і 30-тонні машини з дуже обмеженими можливостями в кінці 50-х років. І ось на початку XXI ст. ми маємо компактний 30-кілограмовий набір пристроїв з колосальними потенційними можливостями.

Працювати комп'ютер змушує машинна мова. Користувач може навіть і не здогадуватись про її існування. Спілкуватись з комп'ютером користувачу допомагають операційні системи, офісні пакети, системи програмування і т.д. Використання сучасних технологій програмування дозволяє створювати програми, не написавши жодної стрічки коду. Але в мозок комп'ютера команди все ж таки поступають на машинній мові.

Машинна мова повністю відображає всі архітектурні тонкощі конкретного типу комп'ютерів. Наслідком чого є те, що він індивідуальний для кожного типу ЕОМ. Для того, щоб ефективно використовувати всі можливості комп'ютера, застосовують символічний аналог машинної мови - мову асемблера.

Поширення мікрокомп'ютерів стало причиною перегляду відношення до мови асемблера по двох основних причинах. По-перше, програми написані на асемблері, потребують значно менше пам'яті і часу виконання. По-друге, знання асемблера і результуючого машинного коду дає розуміння архітектури машини, що навряд чи забезпечується при роботі на мові високого рівня.

Метою курсовою роботі є розробка програми для визначення характеристик апаратного середовища системи.

Дана задача є дуже важлива. Тому що, часто виникає необхідність визначення конфігурації системи. Наприклад, при завантажені деяких програм потрібно визначити на якому типі комп'ютера вони завантажується, або ж який об'єм оперативної пам'яті. Деякі пакети САПР, наприклад Autocad, відмовляється працювати, якщо в машині відсутній сопроцесор.

У курсовій роботі я розробив програму автоматизованого вирішення цієї задачі.

1. Постановка задачі

Одним із перших завдань після завантаження задачі є перевірка того куди ми попали: на якому типі комп'ютера запущена задача?... скільки є пам'яті?... чи все необхідне обладнання встановлено? Отже виникає необхідність визначення характеристик апаратного середовища системи.

Програма повинна визначати тип комп'ютера, об'єм оперативної пам'яті, кількість і тип дисководів, кількість підключених COM, LPT та GAME портів, а також чи встановлені CD-ROM та арифметичний сопроцесор. програмування асемблер комп'ютер bios

Математичний сопроцесор - це пристрій, підключений безпосередньо до центрального процесора та призначений для виконання операцій над числами з плаваючою точкою і довгими цілими числами. Він значно розширює можливості комп'ютера по виконанню операцій над числами з дуже великого діапазону значень, а також може обчислювати такі функції, як синус, косинус, тангенс, логарифми і т.д. Основна область використання математичного сопроцесора - наукові розрахунки та машинна графіка.

Оперативна пам'ять або оперативний запам'ятовуючий пристрій - ОЗП (RAM) являє собою сукупність мікросхем з властивістю накопичувати і тимчасово зберігати інформацію. Оперативна пам'ять, яка знаходиться у розпорядженні користувача ПК, може бути розділена на чотири категорії.

Базова пам'ять (conventional memory) - це оперативна пам'ять об'ємом до 640 Кб. Будь-яка програма, що працює під управлінням DOS, може бути завантажена в цю область пам'ять і використовувати її без будь-яких обмежень.

Розширена пам'ять (extended memory) - це оперативна пам'ять більше 1 МБ, що встановлюється на платах розширення. Ця область пам'яті може бути використана програмами, що працюють у середовищі DOS, але легко доступна при роботі операційних систем XENIX, UNIX i OS/2.

Схована пам'ять (shadow memory) - це категорія нарощеної пам'яті в ПК AT (що використовують мікропроцесор Intel 80286). Вона застосовується для резервування областей пам'яті під віртуальні диски, принтерні спулери, області зберігання копій BIOS, а також буфери для операцій обміну з іншими пристроями (кеш-пам'ять).

Додаткова пам'ять (expanded memory) на відміну від розширеної пам'яті за допомогою спеціальної апаратури і програмного забезпечення відображається в діапазон адресів, які лежать нижче границі 1 Мб. Для комп'ютерів IBM PC/XT/AT корпорації Lotus Development, Intel і Microsoft розробили специфікацію розширеної пам'яті (Expanded Memory Specification - EMS).

CD-ROM - це пристрій призначений для читання компакт-дисків (CD).

COM порти - це порти з послідовним типом передачі даних, призначені для під'єднання маніпуляторів, зовнішніх модемів, принтерів і плоттерів, а іноді також електронних ключів (Security Devices), що застосовуються для захисту від неліцензійного використання програмних продуктів.

LPT порти - це порти з паралельним типом передачі даних, призначені для підключення принтерів та інших пристроїв, що вимагають відносно великої швидкості передачі даних, а також можуть використовуватися для з'єднання комп'ютерів між собою для обміну даними.

Дисковод - це пристрій, призначений для читання/запису накопичувачів на гнучких магнітних дисках. Розрізняють такі типи дисководів: 360 Кб, 720Кб, 1.2 Мб, 1.44 Мб, 2.88 Мб.

Існує три способи отримання інформації про встановлене обладнання. Найменш простіший спосіб - запитати про це у користувача (але чи знає він відповіді?). Набагато краще отримати всю доступну інформацію з установки перемикачів на материнській платі. Однак ця установка не завжди відповідає дійсності. Тому найкраще використати третю можливість - отримати прямий доступ до необхідного обладнання або ж прочитати потрібну інформацію з області даних BIOS.

2. Опис алгоритму роботи програми

Алгоритм роботи програми базується на послідовному виклику процедур та виведенню відповідних повідомлень. Блок-схема програми розміщена в Додатку А.

В програмі використовуються такі процедури: comp_type, math, OsnMemSize, ExtMemSize, cd_rom, fdd, ports, game, ByteToStr, WordToStr, DWordToStr.

Процедура comp_type призначена для визначення типу комп'ютера. Після виконання функції C0h переривання INT 15h регістри ES:BX вказують на таблицю в області ПЗУ BIOS. В даній таблиці зі зміщенням (+2) розміром 1 байт міститься код моделі, а зі зміщенням (+3) розміром 1 байт - додатковий код моделі комп'ютера. В Додатку Б подана таблиця кодів та додаткових кодів моделей для деяких широко розповсюджених типів комп'ютерів. Однак функція C0h переривання INT 15h підтримується не всіма версіями BIOS, а тільки тими, що були виготовлені після 10 січня 1986 року. Тому якщо дана функція не підтримується, то зчитується байт коду моделі, що міститься в ПЗУ BIOS по адресу F000h:FFFEh. Після того, як код моделі визначений, встановлюється відповідний тип комп'ютера.

Процедура math використовується для визначення того чи встановлений арифметичний сопроцесор. При запуску ROM-BIOS перевіряє підключене обладнання і заносить результати цієї перевірки в регістр статусу. Цей регістр займає два байти, починаючи з 0040:0010. Переривання INT 11h повертає в AX значення цього регістра. Перевірка 2 біта регістру AX показує чи встановлений арифметичний сопроцесор.

Процедура OsnMemSize застосовується для визначення розміру основної оперативної пам'яті. В регістрах 15h та 16h CMOS містяться відповідно молодший та старший байти значення розміру основної оперативної пам'яті. Зчитаємо за допомогою процедури ReadCmos значення цих регістрів і в AX отримаємо розмір пам'яті та перетворимо його у стрічку символів за допомогою процедури WordtoStr.

Процедура ExtMemSize призначена для визначення розміру розширеної оперативної пам'яті. Функція AX=0E801h переривання INT 15h повертає розмір пам'яті. Але якщо дана функція не підтримується, то значення розміру пам'яті зчитується з регістрів 17h і 18h CMOS за допомогою процедури ReadCmos. В AX:DX отримаємо розмір пам'яті та перетворимо його у стрічку символів використавши процедуру DWordtoStr.

Процедура cd_rom використовується для визначення того чи є встановлений СD-ROM і повертає його ім'я.

Процедура fdd застосовується для визначення типу встановлених дисководів. За допомогою процедури ReadCmos з регістра 10h зчитується слово, і старший байт даного слово містить інформацію про другий дисковод, а молодший байт - інформацію про перший дисковод.

Процедура ports призначена для визначення кількості під'єднаних COM та LPT портів.

Процедура game використовується для визначення того чи під'єднаний GAME порт. Переривання INT 11h повертає в AX "список обладнання". Значення 12 біта даного регістра показує чи встановлений ігровий порт.

Процедура ReadCmos застосовується для читання регістрів Cmos. Для зчитування значення регістра необхідно спочатку послати його номер в порт з адресом 70h, а потім прочитати його через порт 71h.

Процедури ByteToStr, WordToStr, DWordToStr призначені для перетворення байта, слова, подвійного слова в стрічку символів, що закінчується `$'.

3. Тестування програми

Для проведення тестування програми виконаймо файл з іменем kursova.exe. В результаті на екран буде виведена інформація про апаратні характеристики даного комп'ютера (рис. 1), а саме: тип комп'ютера - IBM PC/AT або аналог, математичний сопроцесор встановлений, об'єм основної та розширеної оперативної пам'яті рівний відповідно 640 Кб та 261056 Кб, встановлені перший дисковод (3,5" 1,44 Мб) і один CD-ROM привід (F:), підключені 2 COM, 1 LPT і 1 GAME порти. Тестування програми проводилось на комп'ютері з процесором AMD Athlon(tm) XP, об'ємом оперативної пам'яті 256 Мб та встановленою операційною системою Windows 98.

Рис. 1. Результати виконання програми.

Отже, всі характеристики системи програма визначає правильно.

Однак, тестування програми на комп'ютерах з ОС Windows 2000 показало, що такі параметри, як розмір XMS пам'яті та кількість підключених портів визначаються некоректно.

Висновки

У курсовій роботі я розробив програму встановлення характеристик апаратного середовища системи. Дана програма написана на мові асемблер, що надає їй такі переваги: невеликий розмір, висока швидкість виконання, незначний розмір необхідної пам'яті. Вона може працювати на відносно старих моделях ПК з ОС MS-DOS або Windows 9x. Програма виводить інформацію про:

· тип комп'ютера;

· об'єм оперативної пам'яті;

· математичний сопроцесор;

· COM та LPT порти;

· GAME порт;

· CD-ROM приводи;

· дисководи.

Список використаної літератури

1. В. Юров. ASSEMBLER. - СПб.: Питер, 2002. - 624с.

2. А. Фролов, Г.Фролов. Аппаратное обеспечение IBM PC.- М.: Диалог-МИФИ, 1992.- 408с.

3. Абель П. Язык Ассемблера для IBM PC и программирования / Пер. с англ. Ю.В. Сальникова. - М.: Высш. Шк., 1992. - 447 с.: ил

4. Р. Журден. Справочник программиста на персональном компьютере фирмы IBM.

5. Освоение Turbo Assembler: Пер. с англ. - 2-е изд. - К.; М.; СПб.: Диалектика, 1996. - 544 с.

Додаток А

Блок-схема програми

Додаток Б

Лістинг програми

MODEL small

STACK 256

.data

AnyKey db 10,13,'Натиснiть будь-яку клавiшу..$'

CompType db 'Тип компютера: $'

MathProc db 10,13,'Арифметичний сопроцесор: $'

Memory db 10,13,'Память:$'

OsnMem db 10,13,' Основна [кб]: $'

XmsMem db 10,13,' XMS [кб]: $'

VideoType db 10,13,'Тип вiдеоадаптора: $'

VideoMem db 10,13,'Вiдео-ОЗУ [кб]: $'

FirstFDD db 10,13,'Перший дисковод: $'

SecondFDD db 10,13,'Другий дисковод: $'

CDROM db 10,13,'CD-ROM: $'

COMport db 10,13,'Порти:',10,13,' COM: $'

LPTport db 10,13,' LPT: $'

GAMEport db 10,13,' GAME: $'

yes db 'встановлений$'

no db 'не встановлений$'

Comp_PC db 'IBM PC$'

Comp_PCjr db 'IBM PCjr$'

Comp_PC_Convertible db 'IBM PC Convertible$'

Comp_XT db 'IBM PC/XT$'

Comp_XT_286 db 'IBM PC/XT 286$'

Comp_AT db 'IBM PC/AT або аналог$'

Comp_PS2_25 db 'IBM PS/2 модель 25$'

Comp_PS2_30 db 'IBM PS/2 модель 30$'

Comp_PS2_30_286 db 'IBM PS/2 модель 30 286$'

Comp_PS2_50 db 'IBM PS/2 модель 50$'

Comp_PS2_55SX db 'IBM PS/2 модель 55SX$'

Comp_PS2_60 db 'IBM PS/2 модель 60$'

Comp_PS2_65 db 'IBM PS/2 модель 65$'

Comp_PS2_70 db 'IBM PS/2 модель 70$'

Comp_PS2_70_486 db 'IBM PS/2 модель 70 486$'

Comp_PS2_P70 db 'IBM PS/2 модель P70 Laptop$'

Comp_PS2_80 db 'IBM PS/2 модель 80$'

Comp_PS2_80_16MHz db 'IBM PS/2 модель 80, 16 МГц$'

Comp_PS2_80_20MHz db 'IBM PS/2 модель 80, 20 МГц$'

Comp_PS2_90 db 'IBM PS/2 модель 90$'

Comp_PS1 db 'IBM PS/1$'

Comp_Phoenix_AT db 'Phoenix PC/AT сумiсна BIOS$'

Comp_7552_Gearbox db '7552 Gearbox$'

Comp_Sperry_PC db 'Sperry PC$'

Comp_Compaq_Plus db 'Compaq XT або Compaq Plus$'

Comp_Compaq_PC db 'Compaq PC або Compaq Deskpro$'

Comp_Table dw 0FF2Dh, OFFSET Comp_Compaq_PC

dw 0FF30h, OFFSET Comp_Sperry_PC

dw 0FF9Ah, OFFSET Comp_Compaq_Plus

dw 000F8h, OFFSET Comp_PS2_80_16MHz

dw 001F8h, OFFSET Comp_PS2_80_20MHz

dw 004F8h, OFFSET Comp_PS2_70

dw 009F8h, OFFSET Comp_PS2_70

dw 00BF8h, OFFSET Comp_PS2_P70

dw 00CF8h, OFFSET Comp_PS2_55SX

dw 00DF8h, OFFSET Comp_PS2_70

dw 014F8h, OFFSET Comp_PS2_90

dw 016F8h, OFFSET Comp_PS2_90

dw 01BF8h, OFFSET Comp_PS2_70_486

dw 01CF8h, OFFSET Comp_PS2_65

dw 050F8h, OFFSET Comp_PS2_P70

dw 080F8h, OFFSET Comp_PS2_80

dw 0FFF9h, OFFSET Comp_PC_Convertible

dw 000FAh, OFFSET Comp_PS2_30

dw 001FAh, OFFSET Comp_PS2_25

dw 000FBh, OFFSET Comp_XT

dw 0FFFBh, OFFSET Comp_XT

dw 000FCh, OFFSET Comp_AT

dw 001FCh, OFFSET Comp_AT

dw 002FCh, OFFSET Comp_XT_286

dw 004FCh, OFFSET Comp_PS2_50

dw 005FCh, OFFSET Comp_PS2_60

dw 006FCh, OFFSET Comp_7552_Gearbox

dw 009FCh, OFFSET Comp_PS2_30_286

dw 00BFCh, OFFSET Comp_PS1

dw 081FCh, OFFSET Comp_Phoenix_AT

dw 0FFFCh, OFFSET Comp_AT

dw 0FFFDh, OFFSET Comp_PCjr

dw 0FFFEh, OFFSET Comp_XT

dw 0FFFFh, OFFSET Comp_PC

Comp_Table_Count = ($-Comp_Table)/4

nevid db 'Невiдома$'

FDD_360KB db '5,25" 360кб$'

FDD_1_2MB db '5,25" 1,2Мб$'

FDD_720KB db '3,5" 720кб$'

FDD_1_44MB db '3,5" 1,44Мб$'

FDD_2_88MB db '3,5" 2,88Мб$'

CDROMLetters db 5 DUP(?) ;буфер для номерiв пристроїв

MainSize db 6 DUP(?) ;стрiчка з розмiром основної памятi

XmsSize db 11 DUP(?) ;стрiчка з розмiром памятi XMS

i db 0

k db 0

EmptyStr db ' ','$'

.code

ASSUME ds:@data, es:@data

print macro x

;макрокоманда виводу стрiчки х на екран

mov ah,09h

mov dx,offset x

int 21h

endm

PrintChar macro x

;макрокоманда виводу символа х на екран

mov ah, 02h

mov dl, x

int 21h

endm

clearscr macro

;макрокоманда очистки екрану

mov ah, 00

mov al, 03

int 10h

endm

comp_type proc near

push es

mov ah,0C0h ;AH = функцiя отримання параметрiв конфiгурацiї системи

int 15h ;ES:BX - таблиця системної конфiгурацiї

jc @NoSubmodel

or ah,ah

jz @NoSubmodel

mov ax,es:[bx+2] ;AL = iдентифiкатор машини, AH = додатковий код моделi

jmp @Comp_01

@NoSubmodel:

mov ax,0F000h ;AX = сегмент системної ROM BIOS

mov es,ax

mov al,es:[0FFFEh] ;AL = iдентифiкатор машини

mov ah,0FFh

@Comp_01:

mov bx,OFFSET Comp_Table

mov cx,Comp_Table_Count

@CompLoop:

mov dx,[bx+2]

cmp ax,[bx]

jz @Comp_End

add bx,4

loop @CompLoop

print nevid

@Comp_End: print dx

pop es

ret

comp_type endp

ByteToStr proc near

;перетворення числа в AL у стрiчку символiв

xor ah,ah

WordToStr:

;перетворення числа в AX у стрiчку символiв

xor dx,dx

DWordToStr:

;перетворення числа в DX:AX у стрiчку символiв

push si

push di

mov si,10 ;SI = дільник на 10

xor cx,cx ;CX = лічильник цифр поміщених у стек

@@Next_Digit:

push ax

mov ax,dx

xor dx,dx

div si ;AX = старше слово (N / 10)

;DX = (старше слово N) mod 10

mov bx,ax ;BX = старше слово (N / 10)

pop ax ;AX = молодше слово N

div si ;AX = молодше слово (N / 10)

;DX = N mod 10

push dx ;помістити одну цифру в стек

mov dx,bx ;DX = старше слово (N / 10)

inc cx

or bx,ax ;N рівне нулю?

jnz @@Next_Digit

;беремо цифри у зворотному порядку і перетворюємо в символи

cld

@@Store_Digit_Loop:

pop ax ;беремо цифри в зворотному порядку

add al,'0' ;перетворюємо цифру в символ

stosb

loop @@Store_Digit_Loop

mov BYTE PTR es:[di],'$' ;записуємо `$' в кінці стрічки

pop di

pop si

ret

ByteToStr endp

math proc near

int 11h

test al,00000010b

jz vids

print yes

jmp m1

vids: print no

m1:

ret

math endp

ReadCMOS proc near

cli

out 70h, al

jmp SHORT $+2

in al,71h ;AL = значення регiстра CMOS

sti

ret

ReadCMOS endp

OsnMemSize proc near

mov ax,1516h ;AL=16h, AH=15h - номери регістрів RT/CMOS

call ReadCMOS ;зчитуєм старший байт

xchg al,ah

call ReadCMOS ;AX = розмір основної оперативної пам'яті в кілобайтах

mov di, offset MainSize

call WordtoStr

ret

OsnMemSize endp

ExtMemSize proc near

mov ax,0E801h ;AX=0E801h (получить размер памяти)

int 15h ;CF = флаг вдалого/невдалого завершення

; СX = розмір розширеної пам'яті від 1Мб до 16Мб в кілобайтах

; DX = розмір розширеної пам'яті більше 64Мб в 64-кілобайтных блоках

jc @Below64Mb

mov ax,cx

mov bx,dx

mov cl,6

shl bx,cl

mov cl,0Ah

shr dx,cl

add ax,bx

adc dx,0 ;DX:AX = розмір розширеної оперативної пам'яті в кілобайтах

ret

@Below64Mb: mov ax,1718h ;AL=18h, AH=17h - номери регістрів CMOS

call ReadCMOS

xchg al,ah

call ReadCMOS

xor dx,dx ;DX:AX = розмір розширеної оперативної пам'яті в кілобайтах

ret

ExtMemSize endp

fdd proc near

mov ax, 10h ;AL=10h - номер регiстра CMOS

call ReadCMOS

mov cx, 10h

div cl

mov i,ah

mov cl,2

jmp @@fd

@fd: print SecondFDD

mov al, i

@@fd: mov dx, offset no

cmp al, 0

je fd

mov dx,OFFSET FDD_360KB

cmp al,1

je fd

mov dx,OFFSET FDD_1_2MB

cmp al,2

je fd

mov dx,OFFSET FDD_720KB

cmp al,3

je fd

mov dx, OFFSET FDD_1_44MB

cmp al,4

je fd

mov dx, OFFSET FDD_2_88MB

fd: print dx

loop @fd

ret

fdd endp

ports proc near

push es

xor bx, bx

mov ax, 0040h

mov es, ax

@@port: mov ax,[es]:[si]

cmp ax, 0000h

je @port

inc bl

@port: inc si

inc si

loop @@port

add bl, 30h

mov EmptyStr[0], bl

print EmptyStr

pop es

ret

ports endp

game proc near

mov EmptyStr[0],'0'

int 11h ;AX = список обладнання в побітовому кодуванні

test ah,10h ; бит 4: 1 = ігровий адаптер встановлений

jnz @game

mov dx,200h ;DX = порт ігрового адаптера

in al,dx

cmp al,0FFh

jne @game

inc dx

in al,dx

cmp al,0FFh

je @@game

@game: mov EmptyStr[0],'1'

@@game: print EmptyStr

ret

game endp

cd_rom proc

xor bx,bx

mov ax, 1500h

int 2fh

cmp bx, 0

jne @cd

print no

jmp @@cd

@cd: push bx

mov ax,150Dh

mov bx,OFFSET CDROMLetters ;ES:BX -> буфер для номерів пристроїв CD-ROM

int 2Fh

cld

pop cx

mov si, OFFSET CDROMLetters

cd_let: lodsb

add al,'A'

PrintChar al

PrintChar ':'

PrintChar ' '

loop cd_let

@@cd:

ret

cd_rom endp

main proc

mov ax, @data ;загрузка сегментних регiстрiв

mov ds, ax

mov es, ax

clearscr

print CompType

call comp_type

print MathProc

call math

print Memory

print OsnMem

call OsnMemSize

print MainSize

print XmsMem

call ExtMemSize

mov di, offset XmsSize

call DWordtoStr

print XmsSize

print FirstFDD

call fdd

print CDROM

call cd_rom

print COMport

xor si, si

mov cx, 4

call ports

print LPTport

mov cx, 3

call ports

print GAMEport

call game

print AnyKey

mov ah, 0

int 16h

exit: ;вихiд

mov ax, 4c00h

int 21h

main endp

end main

Размещено на Allbest.ru

...